; This is test of many of the features of the Installer
; Prints out debugging info if run from CLI

(transcript "On making \"T:Fred\"...")

(makedir "T:fred"
	(prompt "I will now create the directory \"T:Fred\"")
	(help @makedir-help)
	(infos)
	(confirm)
)

(copyfiles
	(prompt "Copying all devices to Fred.")
	(help @copyfiles-help)
	(source "DEVS:")
	(dest "T:fred/angie")
	(pattern "#?.device")
	(files)
	(confirm)
)

(copylib
	(prompt "Copying one device to Fred.")
	(help @copylib-help)
	(source "LIBS:version.library")
	(dest "T:fred/angie")
	(confirm)
)

(startup "FredApp"
	(prompt
		"Some instructions need to be added to the \"S:user-startup\" so that your system will be properly configured to use FredApp.")
	(help "No help for this function")
	(command "assign Fred: T:\n")
)

(tooltype 
	(prompt "Tooltype test")
	(help "No help here either")
	(dest "T:fred")
	(noposition)
	(confirm)
)

(textfile
	(prompt "Creating a textfile...")
	(help "The 'NO HELP' generation continues!")
	(dest "T:fred/prayer")
	(append "In the begining there was the Amiga 1000, and this was good...\n")
	(include "DEVS:Mountlist")
	(confirm)
)

(run "info >t:fred/result"
	(prompt "Running 'info'")
	(help "This will only work from the CLI!")
	(confirm)
)

(if @pretend
	(makeassign "FRED" "T:" (safe))
	(makeassign "FRED" "T:fred")
)

(rename "Fred:result" "Fred:data"
	(prompt "Renaming 'result' to 'data'")
	(help "So why wasn't it named that in the first place??")
	(confirm)
)

(delete "FRED:angie/printer.device"
	(prompt "Going to delete Fred's printer.")
	(help "That's nice...")
	(confirm)
)

(message "End of first set of tests!")

(set name
	(askdir
		(prompt "OK, where was that directory??")
		(help @askdir-help)
		(default "FRED:")
	)
)

(debug "Directory was " name)

(set name
	(askfile
		(prompt "OK, where was that file??")
		(help @askfile-help)
		(default "FRED:angie")
	)
)

(debug "File was " name)

(set name
	(askstring
		(prompt "OK, what should I have named that data file?")
		(help @askstring-help)
		(default "happy_file")
	)
)

(debug "String was " name)

(set name
	(asknumber
		(prompt "How old are you?")
		(help @asknumber-help)
		(range 1 150)
		(default 32)
	)
)

(debug "Number was " name)

(set name
	(askchoice
		(prompt "How do you rate things so far?")
		(help @askchoice-help)
		(choices "Pretty good" "OK" "Only fair" "Rather dismal")
		(default 0)
	)
)

(debug "Choice was " name)

(set name
	(askoptions
		(prompt "What would you like to eat?")
		(help @askoptions-help)
		(choices "Hamburger" "Fries" "Salad" "Strawberry Shake" "Apple Pie")
		(default 9)
	)
)

(debug "Options bits were " name)

(set name
	(askbool
		(prompt "Should Puerto Rico become the next state?")
		(help "It's up to YOU.")
		(choices "Make a State" "Nuke 'Em")
		(default 0)
	)
)

(debug "Result of AskBool was " name)

(trap	1
	(askbool
		(prompt "Please hit ABORT!")
		(help "Pretty please...")
	)
)

(abort
	 "Well, I hope you liked this test of the emergency installer system!"
)